当前位置 主页 > 服务器问题 > win服务器问题汇总 >

    win2003 IIS+MySQL服务管理助手

    栏目:win服务器问题汇总 时间:2018-11-26 10:06

    应一个朋友要求写了这个批处理程序,主要用途就是在win32系统中方便停止、开启、重启IIS、MySQL服务。 提示:如果你安装MySQL的服务名不是mysql,请使用文本编辑器打开该bat文件,批量替换文件中的mysql。
    mysql.bat 程序源码
    使用方法:将下面的文件复制保存为mysql.bat直接运行即可,如果你的服务器禁止了bat的运行请自行修改。
    复制代码 代码如下:
    @Echo Off
    TITLE IIS6+MySQL服务管理助手v0.1

    :start
    CLS
    COLOR 1f
    :: 使用COLOR命令对控制台输出颜色进行更改
    MODE con: COLS=31 LINES=18
    :: MODE语句为设定窗体的宽和高
    Set tm1=%time:~0,2%
    Set tm2=%time:~3,2%
    Set tm3=%time:~6,2%
    Echo %date% %tm1%点%tm2%分%tm3%秒
    Echo ==============================
    Echo 请选择要进行的操作,然后按回车
    Echo ───────────────
    Echo 1. 停止IIS服务
    Echo 2. 启动IIS服务
    Echo 3. 重启IIS服务
    Echo 4. 停止MySQL服务
    Echo 5. 启动MySQL服务
    Echo 6. 重启MySQL服务
    Echo 7. 刷新当前时间
    Echo 8. 作者链接
    Echo 9. 退出本程序
    Echo.

    :menu
    Set Choice=
    Set /P Choice=选择:
    :: 设定变量"Choice"为用户输入的字符
    If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
    :: 如果输入大于1位,取第1位,比如输入132,则返回值为1
    Echo.
    If /I "%Choice%"=="1" Goto iisstop
    If /I "%Choice%"=="2" Goto iisstart
    If /I "%Choice%"=="3" Goto iisrestart
    If /I "%Choice%"=="4" Goto mysqlstop
    If /I "%Choice%"=="5" Goto mysqlstart
    If /I "%Choice%"=="6" Goto mysqlrestart
    If /I "%Choice%"=="7" Goto start
    If /I "%Choice%"=="8" Goto support
    If /I "%Choice%"=="9" Goto End
    :: 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
    :: 注意,If语句需要双等于号
    :: 如果输入的字符不是以上数字,将返回重新输入
    Echo 选择无效,请重新输入
    Echo.
    Goto start

    :iisstop
    CLS
    MODE con: COLS=55 LINES=15
    COLOR 70

    net stop w3svc
    net stop iisadmin /y

    Echo.
    Echo 请按任意键返回...
    PAUSE >nul
    Goto start


    :iisstart
    CLS
    MODE con: COLS=55 LINES=15
    COLOR 70

    net start w3svc

    Echo.
    Echo 请按任意键返回...
    PAUSE >nul
    Goto start


    :iisrestart
    CLS
    MODE con: COLS=31 LINES=15
    COLOR 70

    iisreset.exe

    Echo.
    Echo 请按任意键返回...
    PAUSE >nul
    Goto start


    :mysqlstop
    CLS
    MODE con: COLS=31 LINES=15
    COLOR 70

    net stop mysql

    Echo.
    Echo 请按任意键返回...
    PAUSE >nul
    Goto start


    :mysqlstart
    CLS
    MODE con: COLS=31 LINES=15
    COLOR 70

    net start mysql

    Echo.
    Echo 请按任意键返回...
    PAUSE >nul
    Goto start


    :mysqlrestart
    CLS
    MODE con: COLS=31 LINES=15
    COLOR 70

    net stop mysql
    net start mysql

    Echo.
    Echo 请按任意键返回...
    PAUSE >nul
    Goto start


    :support
    start iexplore "ideacm.com.cn/read.php?72"
    Goto start

    该文章来自 :http://ideacm.com.cn/read.php?72